/**
 * Node Map.
 * 
 * Left-click and drag to move nodes. Right-click on 
 * empty space to make a new node. Right-click and 
 * drag between nodes to make new connections.
 * Middle-click on a node to delete it and its
 * connections.
 *
 * (You can hold down the 'n' key to simulate a right-click or 'd' to simulate a middle click.)
 *
 */
 
 
int num = 2;
Node thisNode = null;
Node currentNode = null;
Node selectedNode = null;
Node startNode = null;
Node deleteNode = null;
ArrayList nodes;
ArrayList connections;
void setup()
{
  size(400,400);
  smooth();
  strokeWeight(1.5);
  strokeCap(ROUND);
  nodes = new ArrayList();
  for(int i=0; i<num; i++) {
    new Node(width/2, (height/(num+1)*(i+1)), 15, nodes);
  }
  connections = new ArrayList();
  for(int i=0; i<nodes.size(); i++) {
    for(int e=i; e<nodes.size(); e++) {
      if ((Node)nodes.get(i) != (Node)nodes.get(e)){
        new Connection((Node)nodes.get(i), (Node)nodes.get(e), connections);
      }
    }
  }
}

void draw()
{
  currentNode = null;
  for(int i=0; i<nodes.size(); i++)
  {
    if (((Node)nodes.get(i)).over()) {
      currentNode = (Node) nodes.get(i);
    }
  }
  if (selectedNode != null) {
    selectedNode.move(mouseX, mouseY);
  } 
  
  background(0);
  for(int i=0; i<connections.size(); i++) {
    ((Connection)connections.get(i)).display();
  }
  
  
  /* Displays line from startNode to mouse when making connections*/
  if (startNode != null) {
    stroke(0,255,0, 191);
    line(startNode.x, startNode.y, mouseX, mouseY);
  }
  
  for(int i=0; i<nodes.size(); i++) {
    thisNode = ((Node)nodes.get(i));
    if (thisNode == currentNode || thisNode == selectedNode) {
      if (thisNode == deleteNode) {
        thisNode.display(255,0,0);
      } else {
      thisNode.display(0,0,255);
      }
    } else {
      thisNode.display(0,0,0);
    }
  }
}

void mouseReleased()
{
  if (selectedNode != null) {
    selectedNode = null;
  } else if (startNode != null) {
    if (currentNode != startNode && currentNode != null) {
      new Connection(startNode, currentNode, connections);
    }
    startNode = null;
  } else if (deleteNode != null) {
    if (currentNode == deleteNode) {
      currentNode.delete();
      currentNode= null;
    }
    deleteNode = null; 
  }
}

void mousePressed() {
  if ( (mouseButton == LEFT) && !(keyPressed && ((key == 'n') || (key == 'd')) ) ) {
    if (currentNode != null) {
      selectedNode = currentNode;
      nodes.remove(selectedNode);
      nodes.add(selectedNode);
    }
  } else if ( (mouseButton == RIGHT) || (keyPressed && (key == 'n'))) {
    if (currentNode == null) {
      new Node(mouseX, mouseY, 15, nodes);
    } else {
      startNode = currentNode;
    }
  } else if ( (mouseButton == CENTER) || (keyPressed && (key == 'd')) ) {
    if (currentNode != null) {
      deleteNode = currentNode;
    }
  }
}

class Connection
{
  Node aNode;
  int ax, ay;
  Node bNode;
  int bx, by;
  ArrayList others;
  
  Connection(Node ia, Node ib, ArrayList o)
  {
    aNode = ia;
    bNode = ib;
    aNode.connections.add(this);
    bNode.connections.add(this);
    others = o;
    others.add(this);
    update();
  }
  
  void update()
  {
    ax = aNode.x;
    ay = aNode.y;
    bx = bNode.x;
    by = bNode.y;
  }
  
  void display()
  {
    stroke(255, 191);
    line(ax,ay,bx,by);
  }
  
  void delete()
  {
    aNode.connections.remove(this);
    bNode.connections.remove(this);
    others.remove(this);
  }
}

class Node
{
  int x, y;
  int boxx, boxy;
  int size;
  ArrayList others;
  ArrayList connections = new ArrayList();
  
  Node(int ix, int iy, int is, ArrayList o)
  {
    x = ix;
    y = iy;
    size = 15;
    others = o;
    others.add(this);
    update();
  }

  void move(int newX, int newY)
  {
    x = newX;
    y = newY;

    if (x < 0) {x = 0;}
    if (y < 0) {y = 0;}
    if (x > width) {x = width;}
    if (y > height) {y = height;}
    
    update();
  }

  void update()
  {
    boxx = x - size/2;
    boxy = y - size/2;
    for (int i=0; i < connections.size(); i++)
    {
      ((Connection)connections.get(i)).update();
    }
  }
  
  boolean over()
  {
    if(overRect(boxx, boxy, size, size)) {
      return true;
    } else {
      return false;
    }
  }
  
  void display(int redVal, int greenVal, int blueVal) 
  {
    fill(redVal,greenVal,blueVal, 127);
    stroke(255, 127);
    rect(boxx, boxy, size, size);
  }
  
  void delete()
  {
    while (connections.size() != 0) {
      ((Connection)connections.get(0)).delete();
    }
    others.remove(this);
  }
}


boolean overRect(int x, int y, int width, int height) 
{
  if (mouseX >= x && mouseX <= x+width && 
      mouseY >= y && mouseY <= y+height) {
    return true;
  } else {
    return false;
  }
}